Author Topic: Grafikai trükkök (Read 205526 times)

geco · « **Reply #675 on:** 2018.October.04. 11:09:00 »

Szerintem ez lenne a négy színű, ha nem szúrtam el semmit

PutPixel:
.y:     equ  $ + 1
        ld   hl, 0
        xor  a
        srl  h
        rr   l
        rra
        srl  h
        rr   l
        rra
        ld   h, l
        ld   l, a
.x:     equ  $ + 1
        ld   de, 0
        ld   a,01h
        srl  e
        rla
        srl  e
        rla
        ld   c,a
        ld   b, high pixelmask
        ld   a,(bc)
        add  hl, de
        set  7, h
        ld   c, a
        cpl
        ld   b, a
.color: equ  $ + 1
        ld   a, 0
        and  0x0f
        ld   d, high (PixelTable)
        ld   e, a
        ld   a, (de)
        and  c
        ld   c, a
        ld   a, (hl)
        and  b
        or   c
        ld   (hl), a
        ret

        defs low -$
PixelTable
        db   0ffh,0fh,0f0h,00h
pixelmask
        db   88h,44h,22h,11h

geco · « **Reply #676 on:** 2018.October.04. 11:19:45 »

És ez a 2 színű:

Code: [Select]

PutPixel:
.y:     equ  $ + 1
        ld   hl, 0
        xor  a
        srl  h
        rr   l
        rra
        srl  h
        rr   l
        rra
        ld   h, l
        ld   l, a
.x:     equ  $ + 1
        ld   de, 0
        ld   a,01h
        srl  e
        rla
        srl  e
        rla
        srl  e
        rla
        srl  e
        rla
        ld   c,a
        ld   b, high pixelmask
        ld   a,(bc)
        add  hl, de
        set  7, h
        ld   c, a
        cpl
        ld   b, a
.color: equ  $ + 1
        ld   a, 0                   ;szín érték vagy 00h, vagy 0ffh
        and  c
        ld   c, a
        ld   a, (hl)
        and  b
        or   c
        ld   (hl), a
        ret

        defs low -$
pixelmask
        db   80h,40h,20h,10h,08h,04h,02h,01h

geco · « **Reply #677 on:** 2018.October.04. 11:22:18 »

Bocs, a táblázatokat módosítani kellett, mert az első X pozícióba kerül a magasabb érték, a másodikba az alacsonyabb, és így tovább.

Povi · « **Reply #678 on:** 2018.October.04. 15:39:49 »

Quote from: geco on 2018.October.04. 11:09:00

Szerintem ez lenne a négy színű, ha nem szúrtam el semmit

Nekem a 00, f0, 0f, ff pixeltable sorrend jobbnak tűnik.
de a mask még nem az igazi - szőrös lesz a kép

az and 7-et lecseréltem and 3-ra, hogy 0-3 intervallumba legyen a szín

geco · « **Reply #679 on:** 2018.October.04. 16:52:41 »

Quote from: Povi on 2018.October.04. 15:39:49

Nekem a 00, f0, 0f, ff pixeltable sorrend jobbnak tűnik.
de a mask még nem az igazi - szőrös lesz a kép

az and 7-et lecseréltem and 3-ra, hogy 0-3 intervallumba legyen a szín

Igazad van

IstvanV · « **Reply #680 on:** 2018.October.06. 14:52:51 »

Talán működik:

Code: ZiLOG Z80 Assembler

PutPixel:
.y:     equ  $ + 1
        ld   hl, 0
.x:     equ  $ + 1
        ld   de, 0
        ld   h, l
        ld   l, 0
        add  hl, de
        scf
        rr   h
        rr   l
        sra  h
        rr   l
        ld   a, e
        and  03h
        ld   de, pixelmask
        or   e
        ld   e, a
        ld   a, (de)
        ld   c, a
        cpl
        ld   b, a
.color: equ  $ + 1
        ld   a, 0
        and  03h
        ld   e, a
        ld   a, (de)
        and  c
        ld   c, a
        ld   a, (hl)
        and  b
        or   c
        ld   (hl), a
        ret
 
        defs low -$
PixelTable
        db   00h,0f0h,0fh,0ffh
pixelmask
        db   88h,44h,22h,11h
 

IstvanV · « **Reply #681 on:** 2018.October.07. 16:22:40 »

Teszt program a fenti rutin kissé módosított változatával:

[ Guests cannot view attachments ]
[ Guests cannot view attachments ]

Szerk.: optimalizált PutPixel, pontosabb kör rajzolás, és ditherelt pixel rutin.

Povi · « **Reply #682 on:** 2018.October.09. 15:53:16 »

Quote from: IstvanV on 2018.October.07. 16:22:40

Teszt program a fenti rutin kissé módosított változatával:

(Attachment Link)
(Attachment Link)

Szerk.: optimalizált PutPixel, pontosabb kör rajzolás, és ditherelt pixel rutin.

tetszik az LPT készítése, lopom az ötletet

viszont itt vszínűleg elírás van:

Code: [Select]

        ld    bc, 011ch                 ; BORD_VID
        ld    d, 00h
        exos  16
        ld    bc, 011ch                 ; BIAS_VID
        ld    d, 00h
        exos  16
        halt
        halt

ugyanazt a két változót állítod egymás után

viszont a kérdésem az, hogy a két HALT-ra mi szükség van utána?

Zozosoft · « **Reply #683 on:** 2018.October.09. 16:39:35 »

Quote from: Povi on 2018.October.09. 15:53:16

viszont a kérdésem az, hogy a két HALT-ra mi szükség van utána?

Hogy biztosan lefusson videó megszakítás, ami kiírja az új értékeket a Nick-nek.

IstvanV · « **Reply #684 on:** 2018.October.09. 16:46:37 »

Quote from: Povi on 2018.October.09. 15:53:16

ugyanazt a két változót állítod egymás után

Valóban hiba.

Ez egyébként egy régebbi egyszerű "demó" (köröket rajzolt 16 színű módban), amibe beépítettem a 4 színű PutPixel rutint.

Quote

viszont a kérdésem az, hogy a két HALT-ra mi szükség van utána?

Így biztosan be tudja állítani az EXOS az új keret színt és biast video megszakításban, bár itt a gyakorlatban nem sok jelentősége van. Akkor lenne elsősorban, ha a változók állítása után a program azonnal tiltaná az EXOS megszakítás kezelését.

Povi · « **Reply #685 on:** 2018.October.10. 11:18:02 »

Quote from: IstvanV on 2018.October.09. 16:46:37

Így biztosan be tudja állítani az EXOS az új keret színt és biast video megszakításban, bár itt a gyakorlatban nem sok jelentősége van. Akkor lenne elsősorban, ha a változók állítása után a program azonnal tiltaná az EXOS megszakítás kezelését.

Hm... és tényleg! HALT nélkül, és egy HALT-tal is maradt a keretszín.

Povi · « **Reply #686 on:** 2019.August.11. 20:19:18 »

Vízszintes scrollozásra van valami trükk?

Nem kéne teljes képernyő, csak kb. 150 pixel magas, de teljese szélesség (80 karakteres).

Pl. az "Áttörés"-ben hogy csinálják? (persze az nem a legjobb példa, emlékeim szerint kicsit szaggat),
Vagy bármilyen mászkálós játékban, ahol az emberke nagyjából fix helyen van, és a háttér mozog mögötte.

geco · « **Reply #687 on:** 2019.August.12. 08:26:31 »

Quote from: Povi on 2019.August.11. 20:19:18

Vízszintes scrollozásra van valami trükk?

Nem kéne teljes képernyő, csak kb. 150 pixel magas, de teljese szélesség (80 karakteres).

Pl. az "Áttörés"-ben hogy csinálják? (persze az nem a legjobb példa, emlékeim szerint kicsit szaggat),
Vagy bármilyen mászkálós játékban, ahol az emberke nagyjából fix helyen van, és a háttér mozog mögötte.

Sztem az Áttörés újrarajzolja a képet mindig, TVC-ről lett konvertálva.
A legjobb, és leggyorsabb scroll az, ha csak legszélső fél karakter oszlopot másolod minden fázisban, és az LPT címet lépteted eggyel jobbra, így 4 pixeles vízszintes scrollod lesz.

Povi · « **Reply #688 on:** 2019.August.12. 09:03:19 »

Quote from: geco on 2019.August.12. 08:26:31

Sztem az Áttörés újrarajzolja a képet mindig, TVC-ről lett konvertálva.
A legjobb, és leggyorsabb scroll az, ha csak legszélső fél karakter oszlopot másolod minden fázisban, és az LPT címet lépteted eggyel jobbra, így 4 pixeles vízszintes scrollod lesz.

de ha jól értem, és pl. van egy 15 képernyő szélességű pályám, akkor előre le kéne tárolni az egészet, és azelőtt csúsztatom az LPT ablakot? De már egy 3-4 képernyővel teli lesz a memória.
És mi van akkor, ha a pálya véletlenszerű? (pl. random hegyes háttér)

geco · « **Reply #689 on:** 2019.August.12. 09:28:27 »

Quote from: Povi on 2019.August.12. 09:03:19

de ha jól értem, és pl. van egy 15 képernyő szélességű pályám, akkor előre le kéne tárolni az egészet, és azelőtt csúsztatom az LPT ablakot? De már egy 3-4 képernyővel teli lesz a memória.
És mi van akkor, ha a pálya véletlenszerű? (pl. random hegyes háttér)

Nem kell előre legenerálni, generálhatod csak azt az oszlopot, vagy esetleg egy picivel nagyobb területet.
Random hegynél meg generálhatod a Random hegy aktuális fél karakter oszlopát.

Author Topic: Grafikai trükkök (Read 205526 times)

geco

Re: Grafikai trükkök

geco

Re: Grafikai trükkök

geco

Re: Grafikai trükkök

Povi

Re: Grafikai trükkök

geco

Re: Grafikai trükkök

IstvanV

Re: Grafikai trükkök

IstvanV

Re: Grafikai trükkök

Povi

Re: Grafikai trükkök

Zozosoft

Re: Grafikai trükkök

IstvanV

Re: Grafikai trükkök

Povi

Re: Grafikai trükkök

Povi

Re: Grafikai trükkök

geco

Re: Grafikai trükkök

Povi

Re: Grafikai trükkök

geco

Re: Grafikai trükkök