a nagyobb baj, hogy igazából csak 1-fájlos programokat lehetett vele a Commodore floppyjáról betölteni (pl. Hungaroring, Mr. Alex), mert miután az első fált beolvasta, magnón kereste volna a továbbiakat, így meg nem sok értelme van az egésznek...

Erre való az EXOS 19 - az alapértelmezett perifériát lehet vele beállítani. De egyébként a :DIO cbm8 parancs is ezt csinálta

Ma éjjel azt álmodtam, hogy a Népszabadságbanvan egy cikk az ASMON-ról... Ennek nagyon megörültem, és megnéztem a netes archívumot, és kiderült, hogy évek óta van kb. havonta egy cikk az Enterprise-ról a Népszabiban

átírtam a blokk olvasó rutint, most a nullás lapra van belapozva a DE által kapott cím, a P1-en marad a csatorna RAM.
Így eléggé fölgyorsult, most 7447 byte / sec lett az eredmény a korábbi 3960 helyett.

READ_BLCK:
; exos 6

        bit  0, (ix-3)
        jp   nz, RET_NOFN

        ; HL = pointer to buffer
        ld   l, (ix-6)
        ld   h, (ix-5)

        ; DE' = DE
        push de
        exx
        pop  de
        exx

        in   a, (0b0h)
        push af
        di
        call SET_USER_SEGMENT0  ; at return DE points to P0

.loop:  ld   a, b
        or   c
        jr   z, .vege           ; if (BC == 0) { A = 0; goto vege; }

        ld   a, (ix-1)
        or   (ix-2)
        jr   z, .eof

        inc   (ix-4)
        call  z, Read256ByteFromEeprom
        ldi
        exx
        inc   de
        exx
        bit   6, d
        call  nz, SET_USER_SEGMENT0

        inc  (ix-2)
        jp   nz, READ_BLCK.loop
        inc  (ix-1)
        jp   READ_BLCK.loop

.eof:   ld   d, ERR_EOF         ; End of file
        db   020h               ; JR NZ, .. skip next byte
.vege:  ld   d, a               ; no error
        pop  af
        out  (0b0h), a
        ei
        ld   a, d
        ld   (ix-6), l
        ld   (ix-5), h
        exx
        push de
        exx
        pop  de
        ret


Amit viszont nem értek:
a csatorna RAM mindig az 1-es lapon lesz, ha jól értem. (ide mutat az IX regiszter).
Akkor EXOS 6 és 8 esetén, miért az 1-es lapra számoljuk át a DE értékét? Így állandóan lapozgatni kell, ha nekem szükségem van a csatorna RAM-ra (mondjuk ott van a puffer, ott tárolom a fájlméretet, ami alapján nézem, hogy EOF van-e).
Logikusabb lenne nekem a 2-es lapra átszámolni a DE-t, és odalapozni. A 2-es lapon úgyis csak a rendszerszegmens van, szóval szerintem tiltott megszakítás mellett, és CALL / RET / PUSH / POP használata nélkül működne a dolog, mivel ha jól értem, a verem is a rendszerszegmensen van ilyenkor. Aztán a végén persze visszalapoznám a rendszerszegmenst a 2-es lapra. Vélemény? De akár a nullás lapra is tehetném, tiltott megszakítás mellett, és akkor a verem használatáról se kéne lemondanom.

sebességteszt:

közvetlen portírással / olvasással, 256 byte-os puffer-t használva (egyszerre ennyi adatot töltök be az EEPROM-ból) 11700 byte / sec. A 256 bájtnyi adat valójában 2313 bitnyi jel az I2C buszon, ha jól számolom.

Puffer használata nélkül közvetlen port olvasással: 5715 byte / sec, ebben az esetben a 256 bájt valójában 4608 bitnyi infó a buszon, szóval reális a kb. kétszeres sebesség a puffer használata esetén.

Ugyanez a 256 byte-os buffer-es módszer EXOS 6-tal már csak 3960 byte/sec. Szóval van még mit faragni, főleg, hogy pl. minden bájtolvasásnál újra számolom a DE-t az egyes lapra...

Puffer nélkül EXOS 6-tal 3360 byte / sec, szóval minimális a gyorsulás, ebből is látszik, hogy a fő overhead maga az EXOS 6 rutinom, amit még faragni kéne

egyébként ami nem világos nekem az EXOS leírásból: milyen regisztereket kell megőriznem?
az ugye világos, hogy az A-ban adok vissza hibakódot, vagy nullát. BC és DE regiszterben meg eredményt. De pl. mi van olyan hívásoknál, ahol nincs eredmény, csak az A-ban? Pl. EXOS 1 esetén? Akkor BCDE-t is elronthatom? Mi van a vesszős regiszterekkel? Azokat is megváltoztathatom?

Az ide betett kódodban nincs EOF vizsgálat

tudom, azóta változott:
hátha látod a hibát:
az IX-1 és IX-2 a fájlméret negáltját tárolja (IX-2 low byte, IX-1 high byte); ======================================================================

READ_CHR:
; exos 5

        ld   a, (ix-1)
        or   (ix-2)
        ld   a, 0E4h         ; End of file
        ret  z
        call rdChr
        ld   b, a
        xor  a
        ret

rdChr:  ld   a, CMD_RD_BYTE_EEPROM
        out  (port_PIC), a
        jr   $ + 2          ; wait 12T cycle
        in   a, (port_PIC)
       
        inc  (ix-2)
        ret  nz
        inc  (ix-1)
        ret

; ======================================================================

READ_BLCK:
; exos 6

        ld   a, b
        or   c
        ret  z
        ld   a, (ix-1)
        or   (ix-2)
        ld   a, 0E4h        ; End of file
        ret  z
        push de
        in   a, (0b1h)
        ex   af, af'        ; save A
        call SET_USER_SEGMENT
        call rdChr
        ld   (de), a
        ex   af, af'        ; restore A
        out  (0b1h), a
        pop  de
        inc  de
        dec  bc
        jp   READ_BLCK

; ======================================================================

no, közben hozzáadtam EOF vizsgálatot (a file méretet is eltárolom az EEPROM első két byte-ján): WP-ben már beolvassa hibátlanul, ASMON-ban még nem az igazi...