A USING formázza a változó számot vagy karakterláncot a képernyő vagy a nyomtató helyén. Jó irodai munkákhoz.

The Symbiface3 expansion card, as you already know, is a CPC card created by Hans, TMTLogic group, commissioned by Prodatron, creator of the famed SymbOS multi micro-computer operative system.

This means that the SF3 card has been created with a variety of Z80 computers in mind, including our Enterprise.

Actually, being a CPC card, it needs a re-programation of the CPLD that controls its input and output signals, no more being a CPC card except by its connector, that needs to be converted to an Enterprise slot connector by means of a dummy bridge board.

As you can see, it works flawlessly on I/O mode, even on 10Mhz frequency, but it needs some minor fixings on the memory management side to be perfect.

Also, it needs to be integrated on EXOS to be considered "real Enterprise hardware".  For example, the included Real Time Clock, mouse port, USB port, SD port, Wifi module, etc, will be integrated with drivers on the system, allowing natural EXOS access to them. It will be a huge task, that surely will also need rewriting of the SF3 core.

Is by those reasons that the release of the SF3 as an Enterprise product still will take months, sorry.

I have made minor changes on the "webradio.bas" program.

Hans is re-writing the Wifi Engine.

By now, to maintain the Radio reception, the EP has to continually execute 2 SF3 commands in machine code. Also, for example, some radio IPs work at my office but not at home.

Probably this task will be done by the Arm processor on the next SF3 upgrade. Then, this program will be obsolete and re-written.

Azt hiszem, jobbak vagyunk, mint más számítógép-felhasználók. Gondolj például az Amigákra, miután a Commodore 1994-es bukása után még mindig azon ítéletekben vannak, hogy tudják, ki az igazi tulajdonos.

--------

I think we are better than other  computer users. Think for example on Amigas, after the fall of Commodore on 1994 they still are on judgements to know who is the real owner.

Hans(from TMTLogic) has just added a new function to the superb SymbiFace3 card: webradio.

The procedure is to open a socket on the wifi module to the stream IP and then feed the data received to the music player chip. Surely not a great explanation, but is all what I can say about how it is done. The result is impressive, as you can see on this video:

https://youtu.be/Y410lwBRt18 

The two radio stream IPs have been took from https://www.internet-radio.com

The Basic program is very simple(and probably not very neat inside), although a little machine code subroutine has been added to make things faster.

  100 PROGRAM "WEBRADIO.BAS"
  110 TEXT 80
  120 IF SF3_DETECT=1 THEN GOTO 1000
  130 ALLOCATE 95
  140 CODE STREAM_LOOP=HEX$("AF,67,3E,07,D3,41,3E,12,D3,49,7D,D3,49,3E,5A,D3")
  150 CODE =HEX$("41,DB,41,FE,01,28,FA,FE,00,28,03,67,18,3F,DB,4E")
  160 CODE =HEX$("FE,01,28,FA,FE,00,28,03,67,18,32,3E,07,D3,41,3E")
  170 CODE =HEX$("15,D3,49,7D,D3,49,3E,5A,D3,41,DB,41,FE,01,28,FA")
  180 CODE =HEX$("FE,00,28,03,67,18,16,DB,4E,FE,01,28,FA,FE,00,28")
  190 CODE =HEX$("03,67,18,09,3E,03,D3,B5,DB,B5,17,38,A3,C9")
  200 DIM IP(1 TO 5)
  210 LET ACTUAL$="78.129.228.187:8088/stream"
  220 !  let s   :    socket number
  230 !  let d#  :    data to send
  240 !  let c   :    character number
  250 !
  260 ! open tcp webradio
  270 OUT 65,7
  280 OUT 73,5
  290 GOSUB 1010
  300 LET ACTUAL$=A$
  310 ! IP ADDRESS:
  320 OUT 73,IP(1)
  330 OUT 73,IP(2)
  340 OUT 73,IP(3)
  350 OUT 73,IP(4)
  360 ! port number High Low in hexadeximaal  (9000 decimal)
  370 OUT 73,HIGH
  380 OUT 73,LOW
  390 INPUT AT 4,1,PROMPT "Socket number (0-3): ":S
  400 IF S<0 OR S>3 THEN GOTO 390
  410 PRINT
  420 OUT 73,S
  430 OUT 65,90
  440 GOSUB 760 ! response ARM
  450 GOSUB 830 ! response wifi
  460 !
  470 ! send data request to  TCP
  480 !
  490 LET D$="GET /"&TAG$&" HTTP/1.1"&CHR$(13)&CHR$(10)&CHR$(13)&CHR$(10)
  500 OUT 65,7
  510 OUT 73,8
  520 OUT 73,S
  530 LET L=LEN(D$)
  540 FOR T=1 TO L
  550   LET C=ORD(D$(T:T))
  560   PRINT CHR$(C);
  570   OUT 73,C
  580 NEXT
  590 OUT 65,90
  600 GOSUB 760 ! response ARM
  610 GOSUB 830 ! response wifi
  620 PRINT "Request is send ok"
  630 PRINT :PRINT "press ESC to exit from this stream"
  640 LET ERROR=USR(STREAM_LOOP,S)
  650 PRINT
  660 IF S<>0 THEN PRINT "ERROR:";S
  670 GOSUB 760 ! response ARM
  680 GOSUB 830 ! response wifi
  690 OUT 65,7:OUT 73,10:OUT 73,S:OUT 65,90
  700 GOSUB 760 ! response ARM
  710 GOSUB 830 ! response wifi
  720 OUT 65,7:OUT 73,0:OUT 73,1:OUT 65,90
  730 GOSUB 760 ! response ARM
  740 GOSUB 830 ! response wifi
  750 TEXT :GOTO 260
  760 ! check response ARM
  770 !
  780 IF IN(65)=1 THEN GOTO 780
  790 IF IN(65)=0 THEN RETURN
  800 PRINT "ARM Error "
  810 LET ERROR=USR(STREAM_LOOP,S)
  820 PRINT S:STOP
  830 ! check response wifi
  840 !
  850 IF IN(78)=1 THEN GOTO 850
  860 IF IN(78)=0 THEN RETURN
  870 PRINT "WIFI ERROR"
  880 RETURN
  890 !
  900 DEF SF3_DETECT
  910   NUMERIC A,B
  920   ! Output : Z=detected , NZ=not detected
  930   LET SF3_DETECT=0
  940   OUT 79,170 ! 10101010d
  950   LET A=IN(79) !4Fh system databus echo
  960   OUT 79,85 ! 01010101d
  970   LET B=IN(79)
  980   IF A<>170 OR B<>85 THEN LET SF3_DETECT=1
  990 END DEF
 1000 PRINT :PRINT "SF3 not found":STOP
 1010 !IP input
 1020 LET COUNT=1:LET TAG$="":LET C1=1:LET C2=1:LET CHA=46
 1030 PRINT AT 2,1:"Example: XXX.XXX.XXX.XXX:CCCC/xxxxxxx"
 1040 PRINT AT 1,10:ACTUAL$
 1050 LINE INPUT AT 1,1,PROMPT "IP?      ":A$
 1060 LET L=LEN(A$)
 1070 FOR B=1 TO 4
 1080   LET IP(B)=0
 1090   IF B=4 THEN LET CHA=58
 1100   IF A$(C2:C2)<>CHR$(CHA) THEN
 1110     LET C2=C2+1
 1120     IF C2>L THEN GOTO 1020
 1130     GOTO 1100
 1140   END IF
 1150   LET IP(B)=INT(VAL(A$(C1:C2-1)))
 1160   IF IP(B)<0 OR IP(B)>255 THEN GOTO 1020
 1170   LET C2=C2+1
 1180   LET C1=C2
 1190 NEXT B
 1200 LET IP(5)=0
 1210 IF A$(C2:C2)<>"/" THEN
 1220   LET C2=C2+1
 1230   IF C2>L THEN GOTO 1020
 1240   GOTO 1210
 1250 END IF
 1260 LET IP(5)=INT(VAL(A$(C1:C2-1)))
 1270 IF IP(5)<0 OR IP(5)>65535 THEN GOTO 1020
 1280 LET C2=C2+1
 1290 IF C2>L THEN GOTO 1020
 1300 LET TAG$=LTRIM$(RTRIM$(A$(C2:L)))
 1310 IF TAG$="" THEN GOTO 1020
 1320 !PRINT :PRINT "Good IP! :  ";STR$(IP(1));".";STR$(IP(2));".";STR$(IP(3));".";STR$(IP(4));":";STR$(IP(5));"/";TAG$
 1330 LET HIGH=INT(IP(5)/256):LET LOW=IP(5)-(HIGH*256)
 1340 RETURN

START:
        xor a
        ld h,a
        ld a, 7 ;check RX wifi socket buffer
        out (65),a
        ld a, 18
        out (73),a
        ld a, l
        out (73),a
        ld a, 90
        out (65),a
ARM1:
        in a,(65)
        cp 1
        jr z,ARM1
        cp 0
        jr z,WIFI1
        ld h,a
        jr END
WIFI1:
        in a,(78)
        cp 1
        jr z,WIFI1
        cp 0
        jr z,CONT
        ld h,a
        jr END
CONT:
        ld a, 7 ;copy incoming socket data to mp3 stream
        out (65),a
        ld a, 21
        out (73),a
        ld a, l
        out (73),a
        ld a, 90
        out (65),a
ARM2:
        in a,(65)
        cp 1
        jr z,ARM2
        cp 0
        jr z,WIFI2
        ld h,a
        jr END
WIFI2:
        in a,(78)
        cp 1
        jr z,WIFI2
        cp 0
        jr z,KEYS2
        ld h,a
        jr END
KEYS2:
        ld a,3
        out (181),a
        in a,(181)
        rla
        jr c,START
END:
        ret

The problem with GET is that it is trapped by the PC RTS/CTS protocol, STATUS_IN is set(negative on the signal) even if there is nothing to receive from the PC, so the Enterprise waits forever. Is for that I have used a "conversation" scheme instead of the Half duplex one. The control is alternated between the PC and the Enterprise when an Enter is received(13, Ctrl+M).

There is a serial card, the schematics is here. It was a Hungarian "classic-time" project intended for use with serial mice(or serial external keyboard), but has been superseded by the EnterMice.

The Mouse driver deals(more or less) with that card. You can peek on the code if you want to know how it can be accessed. It is based on a PC UART, so it can be used for other tasks.

Also on classic times, a Danish firm developed an external serial card, even they run for a time an Enterprise oriented BBS. The software has been preserved, but not the hardware.