Azt hittem, hogy gyorsabb lesz, de nem. Alt+W-vel egész jó.

Zzzippel lefordítva is egész jó. Ebbe is meg lehetne majd próbálni valami egyszerű Himnusz zenét tenni.
A Zzzip a leghosszabb sort nem csípte, azt kellett szétszedni, és a bonyolult RGB függvény sem jött be neki, azok értékét kiírattam basicben, és a kapott színkódot írtam bele. A SET STATUS OFF és a TEXT 40 az elejére került, hogy az átdefiniálódó karakterek ne látsszanak a képernyőn, ahogy megváltoznak.
[ Guests cannot view attachments ]
[ Guests cannot view attachments ]

100 PROGRAM "FLAG"
110 NUMERIC BMP(0 TO 7,0 TO 8)
112 SET STATUS OFF
114 TEXT 40
120 CALL FONT
130 CALL INIT
140 CALL WAVE
150 CALL EXIT
1000 DEF INIT
1030   SET 27,144
1040   SET #102:PALETTE 144,144,144,144
1050   SET VIDEO MODE 0
1060   SET VIDEO COLOUR 0
1070   SET VIDEO X 40
1080   SET VIDEO Y 6
1090   FOR I=1 TO 3
1100     OPEN #I:"VIDEO:"
1110     DISPLAY #I:AT I*6-2 FROM 1 TO 6
1130     FOR J=1 TO 6
1135       LET X1=J+I*6-6:LET X2=J+24+I*6
1137       LET XX$="ABCDEFGHABCDEFGHABCDEFGHABCDEFGHABCDEFGHABCDEFGH"
1140       PRINT #I,AT J,5:XX$(X1:X2);
1150     NEXT J
1160   NEXT I
1164   SET #1:PALETTE 144,73,144,144
1166   SET #2:PALETTE 144,255,144,144
1167   SET #3:PALETTE 144,146,144,144
1170 END DEF
1400 DEF EXIT
1410   FOR I=1 TO 3
1420     CLOSE #I
1430   NEXT I
1440   SET 27,0
1450   TEXT 40
1460   SET STATUS ON
1470   CLEAR FONT
1480 END DEF
1600 DEF FONT
1610   DATA 0,0,0,24,24,24,0,0,0
1620   DATA 0,0,60,60,60,60,60,0,0
1630   DATA 0,126,126,126,126,126,126,126,0
1640   DATA 255,255,255,255,255,255,255,255,255
1650   DATA 255,255,255,255,255,255,255,255,255
1660   DATA 0,126,126,126,126,126,126,126,0
1670   DATA 0,0,60,60,60,60,60,0,0
1680   DATA 0,0,0,24,24,24,0,0,0
1690   RESTORE
1700   FOR I=0 TO 7
1710     FOR J=0 TO 8
1720       READ BMP(I,J)
1730     NEXT J
1740     SET CHARACTER 65+I,BMP(I,0),BMP(I,1),BMP(I,2),BMP(I,3),BMP(I,4),BMP(I,5),BMP(I,6),BMP(I,7),BMP(I,8)
1750   NEXT I
1760 END DEF
2600 DEF WAVE
2610   X=0
2620   FOR I=0 TO 7
2630     J=MOD(X+I,8)
2640     SET CHARACTER 65+I,BMP(J,0),BMP(J,1),BMP(J,2),BMP(J,3),BMP(J,4),BMP(J,5),BMP(J,6),BMP(J,7),BMP(J,8)
2650   NEXT I
2660   X=MOD(X+1,8)
2670   IF INKEY$="" THEN 2620
2680 END DEF