Ide jöhet mindenféle kérdés-válasz a témában

Elsõként EPROM lebegés vizsgáló Povinak:
[asm]
          ORG 1000H
          LD A,SZEGMENSSZAM
          OUT (0B1H),A
          LD HL,4000H
          LD B,L
LEBEG1    LD A,(HL)
LEBEG2    CP (HL)
          RET NZ
          DJNZ LEBEG2
          INC HL
          BIT 7,H
          JR NZ,LEBEG1
          RET
          END
[/asm]

Az EP-s fordítók szerintem onnan ismerik fel, hogy a sor elsõ karakterén kezdõdõ szó

Meg is néztem most, Asmon, Fenas, Heass mind így kezeli. Heass-ben lehet kettõspont, de nem kötelezõ.

Az asmonban és a fenasban is lehet kettõspont, de nem kötelezõ. (mostanság fenas-t használok, de ha lenne heass-om romban, akkor azt használnám...). Az a baj, hogy a heass.ext-tel nem tudok fordítani. (nem tudom, miért)

Így van!

A rendszerszegmensen hol kezdõdik a karakterkészlet? Nem találom ez Enterpress-eimet.

Itt a "vinyószimulátor" forráskódja:

                ORG 0C000H
                VAR 64,EXDEXT.ROM
                DB "EXOS_ROM"
                DW 0
                LD A,C
                CP 7
                JR NZ,NEMRAM
                LD DE,DARAB*60H+3
                LD BC,100H
                RET
NEMRAM          IN A,(0B1H)
                OR A
                RET Z
                LD A,C
                CP 2
                JR Z,COM1 ;PARANCSFUZER
 
                CP 3
                RET NZ
                LD A,B
                OR A
                JR Z,ALTAL
                LD HL,EXDEXT
                CALL KERD
                RET NZ
                LD BC,HOSSZ2
                LD DE,HH2
                LD A,255
                EXOS 8
                LD C,0
                RET
ALTAL           PUSH DE
                PUSH BC
                LD DE,HH2
                LD BC,HOSSZ1
                LD A,255
                EXOS 8
                POP BC
                POP DE
                RET
 
COM1            LD HL,EXDOSFF
                CALL KERD
                RET NZ
                LD A,(IY+0)
                OR A
                RET NZ
                PUSH IY
                POP DE
                IN A,(0B2H)
                LD B,A
                LD (IY+0),DARAB
                LD HL,KEZELOP
                LD (IY+1),L
                LD (IY+2),H
                IN A,(0B3H)
                LD (IY+3),A
                XOR A
                LD C,A
                RET
 
 
KERD            LD A,B
                CP (HL)
                RET NZ
                INC HL
                PUSH BC
                PUSH DE
                INC DE
 
AZONOS          LD A,(DE)
                CP (HL)
                JR NZ,NEMA
                INC HL
                INC DE
                DJNZ AZONOS
NEMA            POP DE
                POP BC
                RET
KEZELOP         CP 3
                JR NZ,NEMBOOT
                LD HL,DISK+0C000H
                LD BC,512
                PUSH IX
                POP DE
                LDIR
                XOR A
                RET
NEMBOOT         CP 4
                JR NZ,NEMOLVAS
                DI
                PUSH BC
                PUSH IX
                POP HL
                EXX
                LD C,0B0H
                IN E,(C)
                INC C
                IN D,(C)
                INC C
                IN L,(C)
                OUT (C),D
                EXX
                INC DE
                LD A,D
                LD C,E
                SLA C
                RLA
                SLA C
                RLA
                SLA C
                RLA
                LD C,A
                IN A,(0B3H)
                ADD A,C
                OUT (0B0H),A
                INC A
                OUT (0B1H),A
                LD H,E
                SLA H
                RES 7,H
                RES 6,H
                LD L,0
                LD D,XH
                LD E,XL
                SET 7,D
                RES 6,D
                SLA B
                LD C,0
                LDIR
                EXX
                OUT (C),L
                DEC C
                OUT (C),D
                DEC C
                OUT (C),E
                EXX
                EI
                PUSH DE
                POP IX
                POP BC
                XOR A
                RET
NEMOLVAS       ;LD A,186
                RET
 
EXDEXT          DB 6,"EXDEXT"
EXDOSFF         DB 6,"EXDOS",0FFH
 
DARAB           EQU 1
 
HH2             DB "EXDEXT version 1.0",13,10
HOSSZ1          EQU $-HH2
                DB "ROMDISK EXDOS bovites",13,10
HOSSZ2          EQU $-HH2
                .PRINTX #$
 
VEGEE           EQU $
                DF 0C200H-$,255
                ORG 200H
DISK            MERGE DISKIMG
                END
 

Érdeklõdés esetén el is magyarázhatom, hogy mit csinál

Hogyan lehet azt megoldani, hogy saját programból, ha kiadom az exdos parancsot, és abból esc-kel visszatérek, ne tûnjöm el a fél képernyõ (amit az exdos kitakart).
Konkrétabban: az atomixben csináltam egy olyat, hogy ha megnyomom a kettõspontot, elõugorjon az exdos. Ha kilépek, tök jól folytatódik minden ott, ahol abbamaradt, leszámítva azt, hogy üres a képernyõ.