Ez megválaszolta a következõnek szánt kérdésemet: mitõl lassul be brutálisan az LDIR, ha az utasítás kódja a videó memóriába kerül. Naivan eddig azt hittem, csak egyszer olvassa be a Z80  és így akkor megúszhatóak a várakozások.
De így akkor egyértelmûen az jön ki, hogy minden esetben gyorsabb a kiírt LDI LDI LDI... sorozat, mint az LDIR. Persze bizonyos mennyiség felett elég memória pazarló ez a módszer

SPSCROLL:
                LD HL,4000H           
                LD DE,4000H-9*80+20   
                LD A,198              
                CALL SPSCROLL1        
                LD HL,4000H-9*80      
                LD DE,4000H+189*80+20 
                LD A,9               
SPSCROLL1   
                LD (SPCEL+1),DE       
                LD (SPCOUNT+1),A      
                LD (SPSAVE+1),SP      
SPKEZD:         
                LD SP,HL              
                POP BC                
                POP DE                
                POP HL                
                POP IX                
                POP IY                
                EXX                  
                POP BC                
                POP DE                
                POP HL                
                POP AF                
                EX AF,AF'             
                POP AF                
                LD (SPKEZD2+1),SP     
SPCEL:          LD SP,4000H-9*80+20   
                PUSH AF               
                EX AF,AF'            
                PUSH AF               
                PUSH HL               
                PUSH DE               
                PUSH BC               
                EXX                  
                PUSH IY               
                PUSH IX               
                PUSH HL               
                PUSH DE               
                PUSH BC               
                LD HL,40              
                ADD HL,SP             
                LD (SPCEL2+1),HL      
 
SPKEZD2:        LD SP,4000H
                POP BC
                POP DE
                POP HL
                POP IX
                POP IY
                EXX
                POP BC
                POP DE
                POP HL
                POP AF
                EX AF,AF'
                POP AF
SPCEL2:         LD SP,4000H-9*80+20
                PUSH AF
                EX AF,AF'
                PUSH AF
                PUSH HL
                PUSH DE
                PUSH BC
                EXX
                PUSH IY
                PUSH IX
                PUSH HL
                PUSH DE
                PUSH BC
                LD HL,80
                ADD HL,SP
                LD (SPCEL+1),HL
                LD HL,(SPKEZD2+1)
                LD BC,80-20
                ADD HL,BC
SPCOUNT:        LD A,200
                DEC A
                LD (SPCOUNT+1),A
                JR NZ,SPKEZD
SPSAVE:         LD SP,0
                RET